First we naively find all the lines on the Clebsh cubic surface excluding those at infinity

clebschFunction[{x1_,x2_,x3_,x4_,x5_}]:=x1^3+x2^3+x3^3+x4^3+x5^3
cubicInCP3[{x_,y_,z_,w_}]:=clebschFunction[{x,y,z,w,-x-y-z-w}]
cubicInC3[{x_,y_,z_}]:=cubicInCP3[{x,y,z,1}]
point[u1_,v1_,u2_,v2_,lambda_]:=lambda {1,u1,v1}+(1-lambda) {-1,u2,v2}
lines=Solve[{cubicInC3[point[u1,v1,u2,v2,0]]==0,cubicInC3[point[u1,v1,u2,v2,1]]==0,cubicInC3[point[u1,v1,u2,v2,2]]==0,cubicInC3[point[u1,v1,u2,v2,3]]==0},{u1,v1,u2,v2}];

It is fun to draw all the lines

findPoint1[line_]:=ReplaceAll[{1,u1,v1},line]
findPoint2[line_]:=ReplaceAll[{-1,u2,v2},line]
createCylinder[line_]:=Cylinder[{findPoint1[line],findPoint2[line]},0.02]
cylinders=Map[createCylinder,lines];
Graphics3D[cylinders]

Let’s combine the surface and lines in one plot

surface=ContourPlot3D[cubicInC3[{x,y,z}]==0,{x,-1,1},{y,-1,1},{z,-1,1},ContourStyle->Opacity[0.5],Mesh->None];
Show[surface,Graphics3D[cylinders]]

Let’s switch to a matrix representation

p1[line_]:={1,u1,v1,1}/.line
p2[line_]:={-1,u2,v2,1}/.line
matrixRep[replacementRep_]:=Simplify[{p1[replacementRep],p2[replacementRep]}]
lineMatrices=matrixRep/@lines;

This makes it easy to test if two lines intersect.

equalsQ[mRep1_,mRep2_]:=MatrixRank[Join[mRep1,mRep2]]==2
intersectQ[mRep1_,mRep2_]:=MatrixRank[Join[mRep1,mRep2]]==3

Permutations

matrixForPerm[perm_]:=Table[If[perm[[i]]==j,1,0],{i,1,4},{j,1,4}]
matrixForPerm[{1,2,4,3}]

Apply each permutation to all our lines

permutationMatrices=matrixForPerm/@Permutations[{1,2,3,4}];
permuteLines[perm_]:=Module[{applyMatrix},applyMatrix[mRep_]:=Transpose[perm.Transpose[mRep]];
applyMatrix/@lineMatrices]

permutationMatrices=matrixForPerm/@Permutations[{1,2,3,4}];
permuteLines[perm_]:=Module[{applyMatrix},applyMatrix[mRep_]:=Transpose[perm.Transpose[mRep]];
applyMatrix/@lineMatrices]
permutedLines=Flatten[permuteLines/@permutationMatrices,1];

Delete duplicates

distinctLines=DeleteDuplicates[permutedLines,equalsQ];
Length[distinctLines]

Compute the intersection matrix

intersectionMatrix=Table[intersectQ[distinctLines[[i]],distinctLines[[j]]],{i,1,27},{j,1,27}];
MatrixForm[intersectionMatrix]